add assert_moves/3

Author: woylie

lib/igniter/test.ex

@@ -201,6 +201,52 @@ defmodule Igniter.Test do
     igniter
   end
 
+  @doc """
+  Asserts that a file was moved to a specific location.
+
+  ## Example
+
+      test_project()
+      |> Igniter.move_file("lib/old_location.ex", "lib/new_location.ex")
+      |> assert_moves("lib/old_location.ex", "lib/new_location.ex")
+  """
+  @spec assert_moves(Igniter.t(), from :: String.t(), to: String.t()) :: Igniter.t()
+  def assert_moves(igniter, from, to) do
+    if Map.has_key?(igniter.moves, from) do
+      actual_to = Map.get(igniter.moves, from)
+
+      assert actual_to == to, """
+      Expected #{inspect(from)} to have been moved to:
+
+          #{to}
+
+      But it was moved to:
+
+          #{actual_to}
+      """
+    else
+      flunk("""
+      Expected #{inspect(from)} to have been moved, but it was not.
+      #{moved_files(igniter)}
+      """)
+    end
+
+    igniter
+  end
+
+  defp moved_files(igniter) do
+    if igniter.moves == %{} do
+      "\nNo files were moved."
+    else
+      files =
+        Enum.map_join(igniter.moves, "\n", fn {from, to} ->
+          "* #{from}\n    ↳ #{to}"
+        end)
+
+      "\nThe following files were moved:\n\n#{files}"
+    end
+  end
+
   def assert_rms(igniter, expected_paths) do
     actual_rms = Enum.sort(igniter.rms)
     expected_rms = Enum.sort(List.wrap(expected_paths))

test/igniter/test_test.exs

@@ -78,4 +78,41 @@ defmodule Igniter.TestTest do
                    end
     end
   end
+
+  describe "assert_moves/3" do
+    test "passes when file is moved" do
+      test_project(files: %{"old.exs" => "content"})
+      |> Igniter.move_file("old.exs", "new.exs")
+      |> assert_moves("old.exs", "new.exs")
+    end
+
+    test "fails when file is not moved" do
+      assert_raise ExUnit.AssertionError,
+                   ~r/Expected \"old.exs\" to have been moved, but it was not.\n\n     No files were moved./,
+                   fn ->
+                     test_project(files: %{"old.exs" => "content"})
+                     |> assert_moves("old.exs", "new.exs")
+                   end
+    end
+
+    test "fails when different file is moved" do
+      assert_raise ExUnit.AssertionError,
+                   ~r/Expected \"one.exs\" to have been moved, but it was not.\n\n     The following files were moved:\n\n     \* two.exs\n         ↳ three.exs/,
+                   fn ->
+                     test_project(files: %{"one.exs" => "content", "two.exs" => "content"})
+                     |> Igniter.move_file("two.exs", "three.exs")
+                     |> assert_moves("one.exs", "three.exs")
+                   end
+    end
+
+    test "fails when file is not moved to a different location" do
+      assert_raise ExUnit.AssertionError,
+                   ~r/Expected \"old.exs\" to have been moved to:\n\n         new.exs\n\n     But it was moved to:\n\n         mature.exs/,
+                   fn ->
+                     test_project(files: %{"old.exs" => "content"})
+                     |> Igniter.move_file("old.exs", "mature.exs")
+                     |> assert_moves("old.exs", "new.exs")
+                   end
+    end
+  end
 end