sphinxcontrib-httpexample/devenv.uv2nix.nix at main · collective/sphinxcontrib-httpexample · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
{
  pkgs,
  config,
  lib,
  inputs,
  ...
}:
let
  cfg = config.languages.python;
  inherit (lib) types mkOption;
  python = cfg.interpreter;
  workspace = inputs.uv2nix.lib.workspace.loadWorkspace {
    workspaceRoot = config.languages.python.workspaceRoot;
  };
  overlay = workspace.mkPyprojectOverlay {
    sourcePreference = "wheel";
    dependencies = {
      "${cfg.pyprojectName}" = cfg.dependencies;
    };
  };
  pythonSet =
    (pkgs.callPackage inputs.pyproject-nix.build.packages {
      inherit python;
    }).overrideScope
      (
        pkgs.lib.composeManyExtensions [
          inputs.pyproject-build-systems.overlays.default
          overlay
          cfg.pyprojectOverrides
        ]
      );
  editableOverlay = workspace.mkEditablePyprojectOverlay {
    root = "$REPO_ROOT";
  };
  editablePythonSet = pythonSet.overrideScope editableOverlay;
in
{
  options.languages.python = {
    interpreter = mkOption {
      default = pkgs.python3;
      type = types.package;
    };
    dependencies = mkOption {
      default = [
        "rf711"
        "dev"
      ];
      type = types.listOf types.str;
    };
    workspaceRoot = mkOption {
      type = types.path;
      default = ./.;
    };
    pyprojectName = mkOption {
      type = types.str;
      default =
        (builtins.fromTOML (builtins.readFile (cfg.workspaceRoot + "/pyproject.toml"))).project.name;
    };
    pyprojectOverrides = mkOption {
      default = final: prev: {
      };
    };
  };
  config = {
    languages.python = {
      uv.package = pkgs.buildFHSEnv {
        name = "uv";
        targetPkgs = pkgs: [
          inputs.uv2nix.packages.x86_64-linux.uv-bin
          python
        ];
        runScript = "uv";
      };
    };
    packages = [
      cfg.uv.package
      config.outputs.python.virtualenv
    ];
    outputs.python =
      let
        pyprojectName =
          (builtins.fromTOML (builtins.readFile (cfg.workspaceRoot + "/pyproject.toml"))).project.name;
      in
      {
        virtualenv = editablePythonSet.mkVirtualEnv "${pyprojectName}-dev-env" {
          "${cfg.pyprojectName}" = cfg.dependencies;
        };
      };
  };
}