Spreadsheet/meson.build at main · elework/Spreadsheet · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
project(
  'io.github.elework.spreadsheet',
  'vala', 'c',
  version: '0.1.0',
  meson_version: '>= 0.59.0',
)

file_name = 'spreadsheet'

i18n = import('i18n')
add_global_arguments(
  '-DGETTEXT_PACKAGE="@0@"'.format(meson.project_name()),
  language:'c',
)

config_data = configuration_data()
config_data.set_quoted('LOCALEDIR', get_option('prefix') / get_option('localedir'))
config_data.set_quoted('GETTEXT_PACKAGE', meson.project_name())
config_file = configure_file(
  input: 'src/Config.vala.in',
  output: '@BASENAME@',
  configuration: config_data,
)

gnome = import('gnome')
asresources = gnome.compile_resources(
  'as-resources',
  'data' / file_name + '.gresource.xml',
  source_dir: 'data',
  c_name: 'as',
)

gnome.post_install(
  glib_compile_schemas: true,
  gtk_update_icon_cache: true,
  update_desktop_database: true,
)

sources = files(
  'src/AlphabetGenerator.vala',
  'src/App.vala',
  'src/Util.vala',
  'src/Functions/Basic.vala',
  'src/Functions/Geometry.vala',
  'src/Models/Cell.vala',
  'src/Models/CellStyle.vala',
  'src/Models/FontStyle.vala',
  'src/Models/Function.vala',
  'src/Models/HistoryAction.vala',
  'src/Models/Page.vala',
  'src/Models/RecentItem.vala',
  'src/Models/Spreadsheet.vala',
  'src/Services/CSV/CSVGrammar.vala',
  'src/Services/CSV/CSVParser.vala',
  'src/Services/CSV/CSVWriter.vala',
  'src/Services/Formula/AST/CallExpression.vala',
  'src/Services/Formula/AST/CellReference.vala',
  'src/Services/Formula/AST/Expression.vala',
  'src/Services/Formula/AST/NumberExpression.vala',
  'src/Services/Formula/AST/TextExpression.vala',
  'src/Services/Formula/FormulaGrammar.vala',
  'src/Services/Formula/FormulaParser.vala',
  'src/Services/FunctionManager.vala',
  'src/Services/HistoryManager.vala',
  'src/Services/Parsing/Evaluator.vala',
  'src/Services/Parsing/Grammar.vala',
  'src/Services/Parsing/Lexer.vala',
  'src/Services/Parsing/Parser.vala',
  'src/Services/Parsing/Token.vala',
  'src/Services/RecentsManager.vala',
  'src/Services/ZoomManager.vala',
  'src/UI/MainWindow.vala',
  'src/UI/WelcomeView.vala',
  'src/Widgets/ActionBar.vala',
  'src/Widgets/FunctionListRow.vala',
  'src/Widgets/RecentListRow.vala',
  'src/Widgets/RoundedSquare.vala',
  'src/Widgets/Sheet.vala',
  'src/Widgets/StyleModal.vala',
)

dependencies = [
  dependency('gee-0.8'),
  dependency('gio-2.0', version: '>= 2.74'), # GLib.ListStore.n_items
  dependency('glib-2.0'),
  dependency('gobject-2.0'),
  dependency('granite-7'),
  dependency('gtk4', version: '>= 4.10'), # Gtk.FileDialog
  dependency('libadwaita-1'),
  dependency('pango'),
]

executable(meson.project_name(),
  asresources,
  config_file,
  sources,
  dependencies: dependencies,
  install: true,
  link_args: ['-lm'],
)

subdir('data')
subdir('po')