Added the test to check if HDEL propagation to replicas after the primary RDB reload

Signed-off-by: Hanxi Zhang <hanxizh@amazon.com>

Author: hanxizh9910

tests/integration/psync2-master-restart.tcl

@@ -221,4 +221,65 @@ start_server {} {
         assert {$digest eq [$replica debug digest]}
         assert {$digest eq [$sub_replica debug digest]}
     }
+
+    test "PSYNC2: Primary reloading RDB will propagate expired hash fields deletion to replica" {
+        # Disable active expiration on master
+        $master debug set-active-expire 0
+        
+        # Create hash with expiring fields and one permanent field
+        $master hsetex myhash PX 1000 FIELDS 3 f1 v1 f2 v2 f3 v3
+        $master hset myhash permanent permanent_value
+        
+        # Wait for replica to sync
+        wait_for_condition 50 100 {
+            [$replica hlen myhash] == 4 &&
+            [$sub_replica hlen myhash] == 4
+        } else {
+            fail "Replicas did not receive hash"
+        }
+        
+        # Wait until all fields are expired
+        wait_for_condition 50 100 {
+            [lindex [$master httl myhash FIELDS 1 f1] 0] == -2 &&
+            [lindex [$master httl myhash FIELDS 1 f2] 0] == -2 &&
+            [lindex [$master httl myhash FIELDS 1 f3] 0] == -2
+        } else {
+            fail "Hash fields did not expire"
+        }
+        
+        # Save RDB
+        $master save
+        
+        # Restart master - this will reload RDB and skip expired fields
+        catch {
+            restart_server 0 true false
+            set master [srv 0 client]
+        }
+        
+        # Wait for replicas to reconnect
+        wait_for_condition 50 1000 {
+            [status $replica master_link_status] eq {up} &&
+            [status $sub_replica master_link_status] eq {up}
+        } else {
+            fail "Replicas didn't sync after master restart"
+        }
+        
+        # Re-enable active expiration
+        $master debug set-active-expire 1
+        
+        # Verify master has only the permanent field
+        assert_equal 1 [$master hlen myhash]
+        assert_equal "permanent_value" [$master hget myhash permanent]
+        
+        # Verify replicas also have only the permanent field (received HDEL)
+        wait_for_condition 50 100 {
+            [$replica hlen myhash] == 1 &&
+            [$sub_replica hlen myhash] == 1
+        } else {
+            fail "Replicas did not delete expired hash fields"
+        }
+        
+        assert_equal "permanent_value" [$replica hget myhash permanent]
+        assert_equal "permanent_value" [$sub_replica hget myhash permanent]
+    }
 }}}